[Dev] [Nonprism/gnome-online-accounts] Upgrade to 3.34.1
theova
theova at bluewin.ch
Wed Nov 6 16:03:37 GMT 2019
Hello,
The following PKGBUILD will upgrade [nonprism/gnome-online-accounts] to
version 3.34.1.
Changelog:
- bumb pkgver and _commit
Tested on 64 bit, built on 64, 32 and arm.
-------------- next part --------------
# $Id$
# Contributor (Arch): Ionut Biru <ibiru at archlinux.org>
# Contributor: Andreas Grapentin <andreas at grapentin.org>
# Contributor: Márcio Silva <coadde at hyperbola.info>
# Contributor: Isaac David <isacdaavid at at@isacdaavid at dot@info>
# Contributor: Theova <theova at member.fsf.org>
# parabola changes and rationale:
# - removed support for possibly unsafe protocols
pkgname=gnome-online-accounts
pkgver=3.34.1
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="Single sign-on framework for GNOME"
pkgdesc+=", without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
arch=(x86_64)
arch+=(i686 armv7h)
license=(LGPL)
depends=(webkit2gtk json-glib libnotify rest libsecret krb5 gcr)
makedepends=(gobject-introspection gtk-doc vala git meson)
optdepends=('gvfs-goa: Virtual file systems, e.g. OwnCloud')
_commit=a57487846b75dccd7a272f8682d647766ce222cd # tags/3.34.1^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-online-accounts.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
}
build() {
arch-meson $pkgname build \
-D lastfm=false \
-D media_server=true \
-D gtk_doc=true \
-D man=true \
-D inspector=true \
-D exchange=false \
-D facebook=false \
-D flickr=false \
-D google=false \
-D pocket=false \
-D windows_live=false \
-D foursquare=false
ninja -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
# vim:set ts=2 sw=2 et:
More information about the Dev
mailing list