# Copyright (C) 2022 Wael Karram <wael@waelk.tech>
# SPDX-License-Identifier: CC0-1.0
# Maintainer: Parabola hackers <dev@lists.parabola.nu>

_pkgname=prosody-modules
pkgname=prosody-community-modules
pkgver=0.12.1
pkgrel=1
pkgdesc="Prosody community modules, includes experimental ones."
arch=('any')
url="https://modules.prosody.im/"
license=('MIT')
depends=('prosody')
makedepends=('mercurial' 'rsync')
mksource=("hg+https://hg.prosody.im/prosody-modules/")
source=("https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.pkg.tar.xz")
mksha1sums=('SKIP')
sha1sums=('SKIP')

mksource() {
	cd "${srcdir}/${_pkgname}"
	# Clean up mercurial files.
	# Remove broken, unmaintained and unlicensed modules:
	# Note that only mod_admin_web seems to downloand nonfree dependencies through a script, and needs better inspection.
	# The rest are unlicensed, unmaintained or invasive to user privacy.
	local nonfree_files=( \.hg \.hgtags mod_admin_web mod_auth_external_insecure mod_bookmarks mod_captcha_registrations mod_compression_unsafe mod_couchdb mod_easy_invite mod_graceful_shutdown mod_pubsub_feeds mod_s2s_auth_monkeysphere mod_twitter mod_aws_profile mod_conversejs mod_pubsub_github mod_pubsub_twitter mod_s2s_auth_posh mod_sentry mod_slack_webhooks mod_sms_free mod_sms_clickatel mod_tweet_data )
	for nonfree_file in "${nonfree_files[@]}"
	do if [[ -d ${nonfree_file} ]]
		then
			rm -r ${nonfree_file}
		else
			echo "cannot delete '${nonfree_file}' - mksource() needs re-working"
			return 1
		fi
	done
}

package() {
	# Make sure that the modules path exists.
	mkdir -p "${pkgdir}/usr/lib/prosody/modules/"
	# Copy the modules.
	cp -r "${srcdir}/${_pkgname}/" "${pkgdir}/usr/lib/prosody/modules/"
}