# Maintainer (aur): Andrea Feletto <andrea@andreafeletto.com>
# Maintainer: Wael Karram <wael@waelk.tech>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
# - delete unlicensed files
# - add openrc service files


pkgname=gmid
pkgver=1.8.4
pkgrel=1
pkgdesc='Fast Gemini server written with security in mind.'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://gmid.omarpolo.com'
license=('ISC')
install=${pkgname}.install
backup=(etc/conf.d/${pkgname}
        etc/${pkgname}.conf)
depends=('libretls' 'libevent')
source=(
	https://github.com/omar-polo/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz
	"gmid.service"
	"gmid.sysusers"
	"gmid.confd"
	"gmid.initd"
	"gmid.conf"
	"index.gmi"
)
sha256sums=(
	'abecdec3bfc2f2deac9d57b84e43334484fc537e5086a3c061f07f6311c89d2f'
	'946de0766343225068a0e3f38cb39a4a93ef312525dd775226b938cd08706b94'
	'6f3814be535099857b579126e5fb5ff9a9a6520d4ea9116c8a0c6a8589ab9ef6'
	'eddbe93741d01077426bc0239db42815c75a0da5191b4e6528df60ae3e0e5bb3'
	'db240698dfb804d203299b3c89015a493c4fe97bec5cb3b3f920e566045191ce'
	'fac76dfe3da74d9dce4ed3acbb6bd0023904140bd71219a7cac06236e2e93d29'
	'361cd4ef2b47437b0f5729d56d0ef88851e56812ab88546c82cda0092fe86139'
)
validpgpkeys=('3954A7AB837D0EA9CFA9798925DB7D9B5A8D4B40') # bill-auger

prepare() {
	cd "$srcdir/$pkgname-$pkgver"

	# Remove unlicensed files, in case they exist.
	if [[ -d contrib ]]
	then
		rm -r contrib
	fi
	if [[ -d site ]]
	then
		rm -r site
	fi
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	MANDIR='usr/share/man/' ./configure --prefix='usr/'
	make
}

package() {
	# Install the config and service files.
	cd "$srcdir"
	install -Dm644 gmid.service -t "$pkgdir/usr/lib/systemd/system"
	install -Dm644 gmid.sysusers -t "$pkgdir/usr/lib/sysusers.d"
	install -Dm644 gmid.confd "$pkgdir/etc/conf.d/gmid"
	install -Dm755 gmid.initd "$pkgdir/etc/init.d/gmid"
	install -Dm644 gmid.conf "$pkgdir/etc/gmid.conf"

	# Install the program files.
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir/" install

	# Install the documentation files.
	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
	install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
	install -Dm644 ../index.gmi "$pkgdir/usr/share/doc/$pkgname/index.gmi"
}