# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=accountsservice-elogind
_pkgname=${pkgname/-elogind}
pkgver=0.6.55
pkgrel=1
pkgdesc="D-Bus interface for user account query and manipulation"
url="https://gitlab.freedesktop.org/accountsservice/accountsservice/"
arch=(x86_64 i686 armv7h)
license=(GPL3)
depends=(glib2 polkit elogind)
provides=($_pkgname)
conflicts=($_pkgname)
makedepends=(gtk-doc gobject-introspection git meson docbook-xsl xmlto)
_commit=6d6f7d62fd18fe5a4d4c06cb1455887ca3abdd1d  # tags/0.6.55^0
source=("git+https://gitlab.freedesktop.org/accountsservice/accountsservice.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}


prepare() {
  cd $_pkgname
  sed -i '/dbus_conf_dir/s/sysconfdir/datadir/g' meson.build
  sed -i '136 d; 137 d; 138 d; 139 d; 140 d; 141 d; 142 d; 143 d' meson.build
  sed -i '40 d; 41 d; 42 d; 43 d; 44 d; 45 d; 46 d; 47 d; 48 d; 49 d; 50 d' data/meson.build
  sed -i '1 d' meson_options.txt
}


build() {
  arch-meson $_pkgname build \
    -D systemd=false \
    -D admin_group=wheel \
    -D elogind=true \
    -D docbook=true \
    -D gtk_doc=true \
    -D user_heuristics=false
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}

# vim:set ts=2 sw=2 et: