[Dev] PKGBUILD updated for epiphany (43.0)

[Iván Ávalos]

Hello! It's been a month since epiphany 43.0 was released. Here's the
updated PKGBUILD, no repatching was needed. I tested with libretools,
of course.
-------------- next part --------------
# Maintainer (arch): Jan Alexander Steffens (heftig) <heftig at archlinux.org>
# Contributor: Jan de Groot <jgc at archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni at gnu.org.pe>
# Contributor: Isaac David <isacdaavid at at@isacdaavid at dot@info>
# Contributor: Iván Ávalos <avalos at disroot.org>
# Contributor: André Silva <emulatorman at hyperbola.info>
# Contributor: Márcio Silva <coadde at hyperbola.info>

# parabola changes and rationale:
#  - rebranded to parabola
#  - switched default searchengine to duckduckgo
#  - removed useless dependency on icu because it's not
#    used at runtime according to readelf -d
#  - pin to sodeps

pkgname=epiphany
pkgver=43.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine"
pkgdesc+=", with DuckDuckGo-HTML search"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(webkit2gtk-4.1 gcr icu libdazzle libhandy libarchive libportal-gtk3
        libsoup3)
depends=( $( sed 's| icu | |' <<<${depends[@]} ) )
depends+=(libhogweed.so)
makedepends=(docbook-xml startup-notification lsb-release gobject-introspection
             yelp-tools git meson)
checkdepends=(xorg-server-xvfb aspell hspell hunspell nuspell libvoikko)
groups=(gnome)
_commit=e5882e2b1fa040fbe6494ee9808591046a6eafa5  # tags/43.0^0
source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit")
source+=(libre.patch)
sha256sums=('SKIP')
sha256sums+=('bf1dd1692ec9f94f8fc669a5ee71dd811d6083465dbb197e3fcc64e2aaf2f709')

# check() requires networking
_run_check=0


pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname

  echo "applying libre.patch"
  patch -Np1 -i ../libre.patch
}

build() {
  arch-meson $pkgname build
  meson compile -C build 
}

check() {
  (( _run_check )) || ! echo "skipping check()" || return 0

  dbus-run-session xvfb-run -s '-nolisten local' \
    meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}