[Dev] Upgrade for [nonprism/gnome-online-accounts] to 3.34.0

[theova]

PKGBUILD for [nonprism/gnome-online-accounts] 3.34.0.

Changelog:
- Update tag
- Add verbose flag to function in check()
- 3.34.0 introduces option for fedora account system
  (https://fedoraproject.org/wiki/Account_System). It is disabled by
  default and I let it as that.

Building:
- The package builds on all 3 supported architectures.

Testing:
- I have tested the x86_64 package by looking at the corresponding
  category in gnome's settings. Only the deserved ones are there.


theova <theova at bluewin.ch> schrieb am Tue, 13. Aug 19 21:44:
>The PKGBUILD attached is the updated version for
>[nonprism/gnome-online-accounts].
>
>Changelog:
>- Generally make PKGBUILD closer to Arch's one
>- Update version and source
>- Remove unneeded dependencies
>- Change to meson build system
>- Add check()
>- Change compile flags:
> - kerberos, owncloud, imap-smtp are enabled per default.
> - Telepathy, Todoist, Twitter and Yahoo support was removed [1] [2]
>   [3] [4]
>
>Testing:
>I have tested the package by looking at the corresponding category in
>gnome's settings. Only the deserved ones are there.
>
>Thanks for updating the package in Parabolas Repo.
>
>
>[1]
>https://gitlab.gnome.org/GNOME/gnome-online-accounts/commit/d44f89f8b9891593ff0fe1b428e1a1253a4667af
>[2]
>https://gitlab.gnome.org/GNOME/gnome-online-accounts/commit/bf77325d847d2878159e8ba2677768b2fe6386a6
>[3]
>https://gitlab.gnome.org/GNOME/gnome-online-accounts/commit/eac46d6de3ba6db904a7dfbe7a82e6db8e12bc4b
>[4]
>https://gitlab.gnome.org/GNOME/gnome-online-accounts/commit/64cfb8183150475465f20631d4e9d4f917d128e3

-------------- next part --------------
# $Id$
# Contributor (Arch): Ionut Biru <ibiru at archlinux.org>
# Contributor: Andreas Grapentin <andreas at grapentin.org>
# Contributor: Márcio Silva <coadde at hyperbola.info>
# Contributor: Isaac David <isacdaavid at at@isacdaavid at dot@info>
# Contributor: Theova <theova at member.fsf.org>

# parabola changes and rationale:
#  - removed support for possibly unsafe protocols

pkgname=gnome-online-accounts
pkgver=3.34.0
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="Single sign-on framework for GNOME"
pkgdesc+=", without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
arch=(x86_64)
arch+=(i686 armv7h)
license=(LGPL)
depends=(webkit2gtk json-glib libnotify rest libsecret krb5 gcr)
makedepends=(gobject-introspection gtk-doc vala git meson)
optdepends=('gvfs-goa: Virtual file systems, e.g. OwnCloud')
_commit=eabe91aec08ce2e1d2b7bb6b67c6ba097aee0ba9  # tags/3.34.0^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-online-accounts.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build \
    -D lastfm=false \
    -D media_server=true \
    -D gtk_doc=true \
    -D man=true \
    -D inspector=true \
    -D exchange=false \
    -D facebook=false \
    -D flickr=false \
    -D google=false \
    -D pocket=false \
    -D windows_live=false \
    -D foursquare=false
  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}

# vim:set ts=2 sw=2 et:
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: not available
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20190915/3f697511/attachment.sig>