[Dev] Updates for flagged packages

[Leo Nunner]

Greetings,

I have updated the "pdsh" and "qutebrowser" packages to their newest
versions. 

changelog:

[pcr] pdsh: Changed version from 2.29 to 2.33 and updated the md5sums.
The URL had to be changed from 
http://pdsh.googlecode.com/files/$pkgname-$pkgver.tar.bz2 to 
https://github.com/chaos/{$pkgname}/releases/download/{$pkgname}-{$pkgver}/{$pkgname}-${pkgver}.tar.gz
. Also, the upstream URL doesn't have the latest version, it seems like
the project moved to GitHub. Added armv7h support. Removed the "rmdir
"${pkgdir}"/usr/sbin" line from the pkgbuild, as it would not build
otherwise, complaining about not being able to find the directory.

[libre] qutebrowser: Changed version from 1.6.2 to 1.6.3 and updated
the sha256sums. I had to compile asciidoc inside the chroot first, as
the signature of the package could not be verified. 
-------------- next part --------------
# Contributor (Arch): drrossum <d.r.vanrossum at gmx.de>
# Contributor (Arch): sh0 <mee at sh0.org>
# Maintainer : Aurélien Desbrières <aurelien at xload.io>

pkgname=pdsh
pkgver=2.33
pkgrel=1
pkgdesc='Parallel Distributed Shell'
url='http://code.google.com/p/pdsh/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('glibc' 'openssh' 'readline')
optdepends=('perl: required by the dshbak utility')
options=('libtool')
source=("https://github.com/chaos/{$pkgname}/releases/download/{$pkgname}-{$pkgver}/{$pkgname}-${pkgver}.tar.gz")
md5sums=('b49e7c1c74480c8d34efd04bf3d0fca2')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --mandir=/usr/share/man \
              --without-rsh \
              --with-ssh \
              --with-dshgroups \
              --with-readline || return 1
  make || return 1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}/" install || return 1
}

# vim:set ts=2 sw=2 et:
-------------- next part --------------
# Maintainer (Arch): Morten Linderud <foxboron at archlinux.org>
# Contributor (Arch): Pierre Neidhardt <ambrevar at gmail.com>
# Contributor (Arch): Florian Bruhin (The Compiler) <archlinux.org at the-compiler.org>
# Maintainer: Omar Vega Ramos <ovruni at gnu.org.pe>
# Contributor: André Silva <emulatorman at hyperbola.info>

# parabola changes and rationale:
#  - removed qt5-webengine dependency
#  - set webkit backend as default

pkgname=qutebrowser
pkgver=1.6.3
pkgrel=1
pkgrel+=.par1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
pkgdesc+=", without nonfree qt5-webengine recommendation"
arch=("any")
url="http://www.qutebrowser.org/"
license=("GPL")
depends=("python-attrs" "python-jinja" "python-pygments" "python-pypeg2"
	"python-pyqt5>=5.7" "python-yaml" "qt5-base>=5.7.1" "qt5-webkit")
makedepends=("asciidoc" "python-setuptools")
optdepends=("gst-libav: media playback"
	"gst-plugins-base: media playback"
	"gst-plugins-good: media playback"
	"gst-plugins-bad: media playback"
	"gst-plugins-ugly: media playback"
	"pdfjs: displaying PDF in-browser")
options=(!emptydirs)
source=("https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz"
	"https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz.asc")
validpgpkeys=("E04E560002401B8EF0E76F0A916EB0C8FD55A072")
sha256sums=('1ed27f8bc7ce3e0d3d1d8687de5280d0be62c899154c773a22196cba49b02a7d'
	    'SKIP')

build() {
	cd "$pkgname-$pkgver"

	# make sure webkit is the default backend
	sed -i 's/webengine/webkit/' qutebrowser/config/configdata.yml

	a2x -f manpage doc/qutebrowser.1.asciidoc
	python setup.py build
}

package() {
	cd "$pkgname-$pkgver"
	make -f misc/Makefile DESTDIR="$pkgdir" PREFIX=/usr install
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: This is a digitally signed message part
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20190717/2314d155/attachment.sig>