[Dev] Update [libre/gnome-boxes]

[theova]

The PKGBUILD below updates [libre/gnome-boxes] to the neweset version
(3.34.2).

Changelog:
- Bumb version
- Rename dependency spice-gtk3 to spice-gtk
- Remove dependency libgovir to follow upstream

Tested on 64, sucessfully built on 32 and arm. To built on arm, I first
needed to built [libr/libosinfo] to have a recent enough version.

gnome-boxes has buttons to download and install non-free GNU/Linux
distributions (as in previous versions). It is not possible to do that,
e message "unsupported protocol https" pops up. Thus I'm not sure if
this is a freedom issue?
-------------- next part --------------
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini at gmail.com>
# Maintainer: Omar Vega Ramos <ovruni at gnu.org.pe>
# Contributor : Isaac David <isacdaavid at at@isacdaavid at dot@info>
# Contributor: Daniel Milewski <niitotantei at gmail.com>
# Contributor : André Silva <emulatorman at hyperbola.info>

pkgname=gnome-boxes
pkgver=3.34.2
pkgrel=1
pkgrel+=.par1
pkgdesc="Simple GNOME application to access remote or virtual systems"
pkgdesc+=", without suggestions (and logos) of nonfree operating systems"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
groups=('gnome')
depends=('cdrtools' 'gtk-vnc' 'libarchive' 'libgudev' 'libosinfo' 'libsecret'
         'libvirt-glib' 'mtools' 'qemu' 'spice-gtk' 'tracker' 'webkit2gtk' 'freerdp')
makedepends=('git' 'gobject-introspection' 'yelp-tools' 'meson' 'spice-protocol' 'vala')
_commit=2edb94153b163759d18195c511d6cf5212fd1bfe  # tags/v3.34.2^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-boxes.git#commit=$_commit"
        "git+https://gitlab.gnome.org/GNOME/gtk-frdp.git"
        "git+https://gitlab.gnome.org/felipeborges/libovf-glib.git")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^v//;s/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.subprojects/gtk-frdp.url "$srcdir/gtk-frdp"
  git config --local submodule.subprojects/libovf-glib.url "$srcdir/libovf-glib"
  git submodule update

  # remove distro logos
  find ./data/osinfo/ -type f -name '*.xml' -exec sed -i '/<os /,/\/os>/ d' {} +
  echo "" > ./data/osinfo/recommended-downloads.xml
  # touch ./data/osinfo/meson.build
  # I'd rather not use Windows as example in user docs
  find ./help/ -type f \( -name '*.po' -o -name '*.page' \) -exec \
       sed -Ei 's/(Microsoft )?Windows(™)?/Parabola/' {} +
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: not available
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20191220/4e12f19a/attachment-0001.sig>