[Dev] [libre/qutebrowser] Update to v1.8.2

[theova]

theova <theova at bluewin.ch> schrieb am Tue, 10. Dec 19 08:05:
>bill-auger <bill-auger at peers.community> schrieb am Mon, 25. Nov 19
>17:40:
>>for that reason, troublesome ones are built separately for each
>>arch. although ideally, they would be built for 'any'
>Couldn't one just replace 'arch=any' with 'arch=(x86_64 i686 armv7h)' to
>make the package different for different arches?
>
>Anyway, Arch 32 has updated the necessary packages and
>[libre/qutebrowser] builds fine on all three architectures.
>Here is the PKGBUILD for the new version 1.8.3.

And this time with cc to mailing list and correct PKGBUILD.
-------------- next part --------------
# Maintainer (Arch): Morten Linderud <foxboron at archlinux.org>
# Contributor (Arch): Pierre Neidhardt <ambrevar at gmail.com>
# Contributor (Arch): Florian Bruhin (The Compiler) <archlinux.org at the-compiler.org>
# Maintainer: Omar Vega Ramos <ovruni at gnu.org.pe>
# Contributor: André Silva <emulatorman at hyperbola.info>

# parabola changes and rationale:
#  - removed qt5-webengine dependency
#  - set webkit backend as default

pkgname=qutebrowser
pkgver=1.8.3
pkgrel=1
pkgrel+=.par1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5"
pkgdesc+=" and QtWebKit, without nonfree qt5-webengine recommendation"
arch=('armv7h' 'i686' 'x86_64')
url="https://www.qutebrowser.org/"
license=("GPL")
depends=("python-attrs" "python-jinja" "python-pygments" "python-pypeg2"
         "python-pyqt5" "python-yaml" "qt5-base" "qt5-webkit")
makedepends=("asciidoc" "python-setuptools")
optdepends=("gst-libav: media playback with qt5-webkit backend"
            "gst-plugins-base: media playback with qt5-webkit backend"
            "gst-plugins-good: media playback with qt5-webkit backend"
            "gst-plugins-bad: media playback with qt5-webkit backend"
            "gst-plugins-ugly: media playback with qt5-webkit backend"
            "pdfjs: displaying PDF in-browser")
options=(!emptydirs)
source=("https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz"
        "https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz.asc"
        "webkit-warning.patch")
validpgpkeys=("E04E560002401B8EF0E76F0A916EB0C8FD55A072") # Florian Bruhin
sha256sums=('c8a9be826c01ec08c3fdcbcab867a6d471d5aaf0ce0a724287a3023ce6afbf14'
            'SKIP'
            '8509032254715a09d807ac5901657e66d0d0780e47bbe2b06f634d7b7c9792d0')

prepare() {
  cd "$pkgname-$pkgver"

  patch -Np1 < $srcdir/webkit-warning.patch
}

build() {
    cd "$pkgname-$pkgver"

    # make sure webkit is the default backend
    sed -i 's/webengine/webkit/' qutebrowser/config/configdata.yml

    make -f misc/Makefile all
}

package() {
    cd "$pkgname-$pkgver"

    make -f misc/Makefile DESTDIR="$pkgdir" PREFIX=/usr install
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: not available
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20191210/85050d73/attachment.sig>