[Dev] Upgrade for [nonprism/duplicity]

[theova]

The attached PKGBUILD upgrades [nonprism/duplicity] to version 0.7.19.

Changelog:
- Upgrade version and md5sums
- Make ncftp as optdepends
- Add new unrecommended packages to pkgdesc
-------------- next part --------------
# Maintainer (Arch): Lukas Fleischer <lfleischer at archlinux.org>
# Contributor (Arch): Kaiting Chen <kaitocracy at gmail.com>
# Contributor (Arch): Aaron Schaefer <aaron at elasticdog.com>
# Contributor: André Silva <emulatorman at hyperbola.info>

# parabola changes and rationale:
#  - removing recommendations for python2-boto python2-dropbox and python2-gdata

pkgname=duplicity
pkgver=0.7.19
pkgrel=1.nonprism1
pkgdesc='A utility for encrypted, bandwidth-efficient backups using the rsync algorithm,'
pkgdesc+='without python2-boto, python2-dropbox, python2-gdata, python2-pydrive, and python2-request-oauthlib recommendation'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='http://www.nongnu.org/duplicity/'
license=('GPL')
depends=('gnupg' 'librsync' 'python2-paramiko' 'python2-fasteners')
makedepends=('python2-setuptools')
optdepends=('lftp: FTPS backend'
            'ncftp: alternative backend for ftp'
            'python2-gobject: GIO backend'
            'gvfs: GIO backend'
            'rsync: rsync backend')
source=("https://launchpad.net/$pkgname/0.7-series/${pkgver}/+download/$pkgname-$pkgver.tar.gz"{,.sig})
md5sums=('b4decdb60275c87b4fafab55c31dc5ce'
         'SKIP')
validpgpkeys=('9D95920CED4A8D5F8B086A9F8B6F8FF4E654E600')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # python2 fix
  for file in $(find . -name '*.py' -print); do
    sed -i 's_^#!.*/usr/bin/python$_#!/usr/bin/python2_' $file
    sed -i 's_^#!.*/usr/bin/env.*python$_#!/usr/bin/env python2_' $file
  done
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  python2 setup.py install --root="$pkgdir" --optimize=1

  # fix broken documentation permissions until upstream does (FS#27301)
  chmod 644 "$pkgdir/usr/share/man/man1/$pkgname.1"
  chmod 644 "$pkgdir/usr/share/man/man1/rdiffdir.1"
  chmod 644 "$pkgdir/usr/share/doc/$pkgname-$pkgver"/*
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: not available
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20190817/9a893489/attachment-0001.sig>