[Dev] Orphan Libre package [khotkeys] marked out-of-date

[jc_gargma]

> jc_gargma at iserlohn-fortress.net wants to notify you that the following
> packages may be out-of-date:
> 
> 
> * khotkeys 5.10.0-1.parabola1 [libre] (i686):
> https://parabolagnulinux.org/packages/libre/i686/khotkeys/ * khotkeys
> 5.10.0-1.parabola1 [libre] (x86_64):
> https://parabolagnulinux.org/packages/libre/x86_64/khotkeys/
> 
> 
> The user provided the following additional text:

I've attached an updated PKGBUILD for khotkeys 5.10.1


-jc
-------------- next part --------------
# $Id: PKGBUILD 291158 2017-03-21 20:15:40Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars at archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea at archlinux.org>
# Contributor (Arch): Antonio Rojas
# Maintainer: André Silva <emulatorman at parabola.nu>

pkgname=khotkeys
pkgver=5.10.1
pkgrel=1.parabola1
pkgdesc='KHotKeys, with DuckDuckGo HTML support'
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/workspaces/plasmadesktop/'
license=('LGPL')
depends=('plasma-workspace')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'kdesignerplugin')
conflicts=('kdebase-workspace')
groups=(plasma)
source=("https://download.kde.org/stable/plasma/${pkgver}/$pkgname-$pkgver.tar.xz"{,.sig})
sha512sums=('bd260215e3a9167d1871e7202268d5214f9f11ddd96bff1ecf37bb6970e6bac26c51c247be06182c3d3de624dc3668d071d0e75027847e9e74c4cd009e4a0ccb'
            'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '348C8651206633FD983A8FC4DEACEA00075E1D76'  # KDE Neon
              'D07BD8662C56CB291B316EB2F5675605C74E02CF') # David Edmundson

prepare() {
  mkdir -p build
  cd ${pkgname}-${pkgver}
  sed -i 's|google[.]com|duckduckgo.com/html|' data/defaults.khotkeys
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: This is a digitally signed message part.
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20170610/64784529/attachment.sig>