[Dev] Orphan Libre package [okular] marked out-of-date

[jc_gargma]

> jc_gargma at iserlohn-fortress.net wants to notify you that the following
> packages may be out-of-date:
> 
> 
> * okular 16.12.1-2.parabola1 [libre] (armv7h):
> https://parabolagnulinux.org/packages/libre/armv7h/okular/ * okular
> 16.12.3-2.parabola1 [libre] (i686):
> https://parabolagnulinux.org/packages/libre/i686/okular/ * okular
> 16.12.3-2.parabola1 [libre] (x86_64):
> https://parabolagnulinux.org/packages/libre/x86_64/okular/
>
> The user provided the following additional text:

I've attached an updated PKGBUILD for 17.04.2


-jc
-------------- next part --------------
# Maintainer (Arch): Felix Yan <felixonmars at archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas at archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea at archlinux.org>
# Maintainer: André Silva <emulatorman at parabola.nu>

pkgname=okular
pkgver=17.04.2
pkgrel=1.parabola1
pkgdesc='Document Viewer, with copy-protection anti-feature turn off by default'
arch=(i686 x86_64 armv7h)
url="https://kde.org/applications/graphics/okular/"
license=(GPL LGPL FDL)
groups=(kde-applications kdegraphics)
depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty kactivities threadweaver kjs kparts mesa)
makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml python chmlib)
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support'
            'khtml: CHM support' 'chmlib: CHM support' 'calligra: ODT and ODP support')
conflicts=(kdegraphics-okular)
replaces=(kdegraphics-okular)
source=("https://download.kde.org/stable/applications/${pkgver}/src/okular-${pkgver}.tar.xz"{,.sig}
        'turn_off_copy-protection_anti-feature.patch')
sha512sums=('5524fb232ab74dda32f003d04b46b77d85c83704300a86eb83008ff00001011d54e98ef0ae7c91d6dbda13016635a3e1a1e37b19b5ab22925f065b31f61c3a92'
            'SKIP'
            'ff5068947d1d841319d1405c5b21b5ddd90571ffb38e14a18b371e2253afb2588a6700d8e212e3e2a4ec3ad1408bb5333929a98720eb597a4813b2329766a588')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid at kde.org>

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver
  patch -p1 -i ../turn_off_copy-protection_anti-feature.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 833 bytes
Desc: This is a digitally signed message part.
URL: <https://lists.parabola.nu/pipermail/dev/attachments/20170608/c633c71e/attachment.sig>